Putting it all together
So far, you’ve learned that Yarn scripts are plaintext files (stored outside of Try Yarn Spinner, they have the .yarn extension). Let’s do a quick recap…
Yarn scripts are composed of nodes, which must always start with at least a title header followed by a ---, and end with a ===:
title: Party
---
===
Inside each node are lines, which are simple lines of dialogue that are delivered to the player, and often have a character name at the beginning:
title: Party
---
Partygoer A: We're having a party!
Partygoer B: Yeah, we are!
===
Lines can also be options, which provide choices to the player:
title: Party
---
Partygoer: We're having a party!
-> I don't like parties.
-> I love parties!
-> PARTY!
===
These options can be nested:
title: Party
---
Partygoer: We're having a party!
-> I don't like parties.
Partygoer: You should.
-> I don't. But I can pretend.
Partygoer: Good idea! Let's party!
-> I prefer to nap.
Partygoer: (whispers) we all do.
-> I love parties!
-> PARTY!
===
You can also have multiple nodes, and jump between them using the jump statement:
title: Party
---
Partygoer A: We're having a party!
Partygoer B: Yeah, we are!
-> I do enjoy a party.
<<jump Enjoy>>
-> I was told to say the password "antiquarian".
<<jump SecretParty>>
===
title: SecretParty
---
Secret Partygoer: Woohoo! That's the password for the secret, better party!
Secret Partygoer: Welcome!
===
title: Enjoy
---
Partygoer A: We all enjoy a party!
Partygoer B: I'll party until I cannot party anymore!
===
And you can declare variables of three different types—numbers, strings, and booleans—and use them in lines, and for flow control. You’ve also learned about conditional options and built-in functions.
The next example recaps everything you’ve learned so far, so build it up slowly, piece by piece, in a new Try Yarn Spinner tab, so you understand how it’s working. Try to improve it, or make it longer by adding conditional options and use of built-in functions.
title: Party
---
<<declare $partyHats = 0>>
Partygoer A: We're having a party!
Partygoer B: Yeah, we are!
Partygoer A: Want a party hat?
-> Yes, please!
<<set $partyHats = $partyHats + 1>>
Partygoer A: Here you go!
Partygoer B: Look over here!
<<jump OverHere>>
-> No, thanks. I despise happiness. I relish misery.
Partygoer A: We see that.
Partygoer B: Why don't you go over there?
<<jump OverThere>>
-> I'd rather go over here...
<<jump OverThere>>
===
title: OverHere
---
Partygoer C: Oh hi. Can I borrow a party hat?
Partygoer C: I lost mine.
<<if $partyHats > 0>>
Partygoer C: Looks like you can spare a hat.
-> Sure, here you go.
<<set $partyHats = $partyHats - 1>>
<<jump OverThere>>
-> No. Never. Absolutely not.
<<jump OverThere>>
<<else>>
Partygoer C: Oh, you don't have any to spare.
Partygoer C: Cya around, I guess.
<<jump Party>>
<<endif>>
===
title: OverThere
---
Partygoer D: Hi!
<<if $partyHats > 0 and $partyHats <= 2>>
Partygoer D: You're definitely fun.
-> Why?
Partygoer D: You like party hats.
-> Thanks! You're fun too.
<<jump Party>>
<<elseif $partyHats > 2>>
Partygoer D: You have too many hats!
Partygoer D: It really scares me.
-> Sorry...
<<jump Party>>
<<else>>
Partygoer D: You should go party somewhere else in this party.
-> Oh, bye, then...
<<jump Party>>
<<endif>>
===
With that all said, in the next part, we’ll take things further and start using Yarn Spinner for Visual Studio Code.
This was the end of the Writing Yarn Scripts section of the documentation! Your next step should be learning to use Yarn Spinner for Visual Studio Code.